-
Notifications
You must be signed in to change notification settings - Fork 1.2k
Expand file tree
/
Copy pathconfigure.ac
More file actions
3296 lines (2880 loc) · 112 KB
/
configure.ac
File metadata and controls
3296 lines (2880 loc) · 112 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#**************************************************************************
#* *
#* OCaml *
#* *
#* Sebastien Hinderer, projet Gallium, INRIA Paris *
#* *
#* Copyright 2018 Institut National de Recherche en Informatique et *
#* en Automatique. *
#* *
#* All rights reserved. This file is distributed under the terms of *
#* the GNU Lesser General Public License version 2.1, with the *
#* special exception on linking described in the file LICENSE. *
#* *
#**************************************************************************
# Process this file with autoconf to produce a configure script.
# Require Autoconf 2.71 for repeatability in CI
AC_PREREQ([2.71])
AC_INIT([OCaml],
[OCAML__VERSION],
[caml-list@inria.fr],
[ocaml],
[http://www.ocaml.org])
AC_MSG_NOTICE([Configuring OCaml version AC_PACKAGE_VERSION])
# Configuration variables
## Command-line arguments passed to configure
CONFIGURE_ARGS="$*"
# Command to build executables
# Ultimately, MKEXE may build an executable using the C compiler or it may use
# a wrapper for a linker (i.e. flexlink). The build system must therefore not
# rely on $CFLAGS because these cannot be processed by flexlink (and are not
# passed)
mkexe_cmd='$(CC)'
mkexe_extra_flags=''
mkexe_via_cc_extra_cmd=''
mkexe_ldflags_prefix=''
mkexe_via_cc_ldflags_prefix=''
# Flags for building executable files with debugging symbols
mkexedebugflag="-g"
common_cflags=""
common_cppflags=""
internal_cflags=""
internal_cppflags=""
bytecode_cflags=""
bytecode_cppflags=""
oc_ldflags=""
oc_dll_ldflags=""
oc_exe_ldflags=""
tsan=false
# TSan flags for each compilation stage
tsan_cppflags="-DWITH_THREAD_SANITIZER"
tsan_cflags="-fsanitize=thread"
tsan_distinguish_volatile_cflags=""
tsan_ldflags="-fsanitize=thread"
# The C# compiler and its flags
CSC=""
CSCFLAGS=""
ostype="Unix"
SO="so"
toolchain="cc"
reserved_header_bits=0
instrumented_runtime=false
instrumented_runtime_libs=""
bootstrapping_flexdll=false
flexdll_dir=
lib_dynlink=false
lib_str=false
lib_systhreads=false
lib_unix=false
optional_libraries=''
optional_bytecode_tools=''
optional_native_tools=''
ocamltest_libunix=None
ocamltest_unix_impl="dummy"
unix_library=""
unix_directory=""
target_libdir_is_relative=false
srcdir_abs=''
srcdir_abs_real=''
build_map_flags=''
runtime_search=''
runtime_search_target=''
# Information about the package
## Source directory
AC_CONFIG_SRCDIR([runtime/interp.c])
## Directory containing auxiliary scripts used during build
AC_CONFIG_AUX_DIR([build-aux])
## Output variables
AC_SUBST([CONFIGURE_ARGS])
AC_SUBST([native_compiler])
AC_SUBST([default_build_target])
AC_SUBST([VERSION], [AC_PACKAGE_VERSION])
AC_SUBST([OCAML_DEVELOPMENT_VERSION], [OCAML__DEVELOPMENT_VERSION])
AC_SUBST([OCAML_RELEASE_EXTRA], [OCAML__RELEASE_EXTRA])
AC_SUBST([OCAML_VERSION_MAJOR], [OCAML__VERSION_MAJOR])
AC_SUBST([OCAML_VERSION_MINOR], [OCAML__VERSION_MINOR])
AC_SUBST([OCAML_VERSION_PATCHLEVEL], [OCAML__VERSION_PATCHLEVEL])
AC_SUBST([OCAML_VERSION_EXTRA], [OCAML__VERSION_EXTRA])
AC_SUBST([OCAML_VERSION_SHORT], [OCAML__VERSION_SHORT])
AC_SUBST([OCAML_RELEASE_NUMBER], [OCAML__RELEASE_NUMBER])
AC_DEFINE([MAGIC_NUMBER_PREFIX], ["][MAGIC_NUMBER__PREFIX]["])
AC_DEFINE([MAGIC_NUMBER_VERSION], ["][MAGIC_NUMBER__VERSION]["])
AC_DEFINE([EXEC_MAGIC_LENGTH], [MAGIC_NUMBER__LENGTH])
AC_SUBST([MAGIC_LENGTH], [MAGIC_NUMBER__LENGTH])
AC_DEFINE([EXEC_FORMAT], ["][EXEC__FORMAT]["])
AC_SUBST([EXEC_MAGIC_NUMBER], [EXEC__MAGIC_NUMBER])
AC_SUBST([CMI_MAGIC_NUMBER], [CMI__MAGIC_NUMBER])
AC_SUBST([CMO_MAGIC_NUMBER], [CMO__MAGIC_NUMBER])
AC_SUBST([CMA_MAGIC_NUMBER], [CMA__MAGIC_NUMBER])
AC_SUBST([CMX_MAGIC_NUMBER])
AC_SUBST([CMXA_MAGIC_NUMBER])
AC_SUBST([AST_IMPL_MAGIC_NUMBER], [AST_IMPL__MAGIC_NUMBER])
AC_SUBST([AST_INTF_MAGIC_NUMBER], [AST_INTF__MAGIC_NUMBER])
AC_SUBST([CMXS_MAGIC_NUMBER], [CMXS__MAGIC_NUMBER])
AC_SUBST([CMT_MAGIC_NUMBER], [CMT__MAGIC_NUMBER])
AC_SUBST([LINEAR_MAGIC_NUMBER], [LINEAR__MAGIC_NUMBER])
AC_SUBST([CC])
AC_SUBST([ocaml_cc_vendor])
AC_SUBST([DEP_CC])
AC_SUBST([DEP_CPPFLAGS])
AC_SUBST([DEP_CC_PREFIX])
AC_SUBST([SAK_BUILD])
AC_SUBST([SAK])
AC_SUBST([encode_C_literal])
AC_SUBST([ocaml_cv_prog_diff_supports_color])
AC_SUBST([CSC])
AC_SUBST([CSCFLAGS])
# Note: This is present for the flexdll bootstrap where it exposed as the old
# TOOLPREF variable. It would be better if flexdll where updated to require
# WINDRES instead.
AC_SUBST([ac_tool_prefix])
AC_SUBST([libext])
AC_SUBST([S])
AC_SUBST([runtime_asm_objects])
AC_SUBST([SO])
AC_SUBST([arch])
AC_SUBST([arch_specific_SOURCES])
AC_SUBST([arch64])
AC_SUBST([model])
AC_SUBST([system])
AC_SUBST([target_os_type])
AC_SUBST([bytecode_cflags])
AC_SUBST([bytecode_cppflags])
AC_SUBST([native_cflags])
AC_SUBST([native_cppflags])
AC_SUBST([oc_bytecode_cflags])
AC_SUBST([oc_bytecode_cppflags])
AC_SUBST([oc_native_cflags])
AC_SUBST([oc_native_cppflags])
AC_SUBST([systhread_support])
AC_SUBST([ocamlsrcdir])
AC_SUBST([unix_or_win32])
AC_SUBST([ln])
AC_SUBST([ocamlyacc_wstr_module])
AC_SUBST([outputexe])
AC_SUBST([outputobj])
AC_SUBST([syslib])
AC_SUBST([fpic])
AC_SUBST([mkexe])
AC_SUBST([mkexe_exp])
AC_SUBST([mkexedebugflag])
AC_SUBST([mkexe_via_cc_ldflags])
AC_SUBST([mkexe_via_cc_extra_cmd])
AC_SUBST([ccomp_type])
AC_SUBST([toolchain])
AC_SUBST([common_cflags])
AC_SUBST([oc_cflags])
AC_SUBST([tsan])
AC_SUBST([tsan_native_runtime_c_sources])
AC_SUBST([common_cppflags])
AC_SUBST([oc_cppflags])
AC_SUBST([oc_ldflags])
AC_SUBST([oc_dll_ldflags])
AC_SUBST([cclibs])
AC_SUBST([native_ldflags])
AC_SUBST([with_nonexecstack_note])
AC_SUBST([zstd_libs])
AC_SUBST([bytecode_cflags])
AC_SUBST([bytecode_cppflags])
AC_SUBST([flexdll_source_dir])
AC_SUBST([bootstrapping_flexdll])
AC_SUBST([flexdll_dir])
AC_SUBST([shebangscripts])
AC_SUBST([launch_method])
AC_SUBST([launch_method_target])
AC_SUBST([AR])
AC_SUBST([mklib])
AC_SUBST([supports_shared_libraries])
AC_SUBST([natdynlink])
AC_SUBST([natdynlinkopts])
AC_SUBST([natdynlink_archive])
AC_SUBST([cmxs])
AC_SUBST([debug_runtime])
AC_SUBST([codegen_invariants])
AC_SUBST([instrumented_runtime])
AC_SUBST([instrumented_runtime_libs])
AC_SUBST([otherlibraries])
AC_SUBST([otherlibs])
AC_SUBST([lib_dynlink])
AC_SUBST([lib_runtime_events])
AC_SUBST([lib_str])
AC_SUBST([lib_systhreads])
AC_SUBST([lib_unix])
AC_SUBST([optional_libraries])
AC_SUBST([optional_bytecode_tools])
AC_SUBST([optional_native_tools])
AC_SUBST([ocamltest_CPP])
AC_SUBST([ocamltest_CXX])
AC_SUBST([ocamltest_libunix])
AC_SUBST([unix_library])
AC_SUBST([unix_directory])
AC_SUBST([cc_has_debug_prefix_map])
AC_SUBST([ocaml_cv_prog_as_debug_prefix_map])
AC_SUBST([as_is_cc])
AC_SUBST([with_debugger]) # TODO: rename this variable
AC_SUBST([build_ocamldebug])
AC_SUBST([build_ocamltex])
AC_SUBST([build_ocamldoc])
AC_SUBST([ocamldoc_target])
AC_SUBST([ocamldoc_opt_target])
AC_SUBST([with_ocamldoc])
AC_SUBST([documentation_tool])
AC_SUBST([documentation_tool_cmd])
AC_SUBST([build_ocamlobjinfo])
AC_SUBST([build_ocamltest])
AC_SUBST([ocamltest])
AC_SUBST([ocamltest_target])
AC_SUBST([ocamltest_opt_target])
AC_SUBST([ASPP])
AC_SUBST([endianness])
AC_SUBST([AS])
AC_SUBST([asm_cfi_supported])
AC_SUBST([asm_size_type_directives])
AC_SUBST([asm_dwarf_version])
AC_SUBST([sharedlib_cflags])
AC_SUBST([rpath])
AC_SUBST([mkdll])
AC_SUBST([mkdll_exp])
AC_SUBST([mkmaindll])
AC_SUBST([mkmaindll_exp])
AC_SUBST([mksharedlibrpath])
AC_SUBST([install_bytecode_programs])
AC_SUBST([install_source_artifacts])
AC_SUBST([install_ocamlnat])
AC_SUBST([reserved_header_bits])
AC_SUBST([frame_pointers])
AC_SUBST([flambda])
AC_SUBST([flambda_invariants])
AC_SUBST([cmm_invariants])
AC_SUBST([windows_unicode])
AC_SUBST([align_double])
AC_SUBST([align_int64])
AC_SUBST([flat_float_array])
AC_SUBST([function_sections])
AC_SUBST([oc_native_compflags])
AC_SUBST([afl])
AC_SUBST([flexdll_chain])
AC_SUBST([PACKLD])
AC_SUBST([build_libraries_manpages])
AC_SUBST([compute_deps])
AC_SUBST([ocaml_prefix])
AC_SUBST([ocaml_bindir])
AC_SUBST([ocaml_libdir])
AC_SUBST([TARGET_LIBDIR])
AC_SUBST([QS])
AC_SUBST([ar_supports_response_files])
AC_SUBST([target_libdir_is_relative])
AC_SUBST([srcdir_abs])
AC_SUBST([srcdir_abs_real])
AC_SUBST([build_map_flags])
AC_SUBST([zinc_runtime_id_lo])
AC_SUBST([zinc_runtime_id_hi])
AC_SUBST([bytecode_runtime_id])
AC_SUBST([native_runtime_id])
AC_SUBST([suffixing])
AC_SUBST([runtime_search])
AC_SUBST([runtime_search_target])
AC_SUBST([cc_extra_warnings])
AC_SUBST([cxx_extra_warnings])
## Generated files
AC_CONFIG_FILES([Makefile.build_config])
AC_CONFIG_FILES([Makefile.config])
AC_CONFIG_FILES([stdlib/sys.ml])
AC_CONFIG_FILES([otherlibs/dynlink/dynlink_config.ml])
AC_CONFIG_FILES([utils/config.common.ml])
AC_CONFIG_FILES([utils/config.generated.ml])
AC_CONFIG_HEADERS([runtime/caml/exec.h])
AC_CONFIG_HEADERS([runtime/caml/m.h])
AC_CONFIG_HEADERS([runtime/caml/s.h])
AC_CONFIG_HEADERS([runtime/caml/version.h])
AC_CONFIG_FILES([compilerlibs/META])
AC_CONFIG_FILES([otherlibs/dynlink/META])
AC_CONFIG_FILES([otherlibs/runtime_events/META])
AC_CONFIG_FILES([stdlib/META])
AS_IF([test -d manual],
[AC_CONFIG_FILES([manual/src/version.tex])
AC_CONFIG_FILES([manual/src/html_processing/src/common.ml])])
# Definitions related to the version of OCaml
AC_DEFINE([OCAML_VERSION_MAJOR], [OCAML__VERSION_MAJOR])
AC_DEFINE([OCAML_VERSION_MINOR], [OCAML__VERSION_MINOR])
AC_DEFINE([OCAML_VERSION_PATCHLEVEL], [OCAML__VERSION_PATCHLEVEL])
m4_if([OCAML__VERSION_EXTRA],[], [],
[AC_DEFINE([OCAML_VERSION_ADDITIONAL], ["][OCAML__VERSION_EXTRA]["])
AC_DEFINE([OCAML_VERSION_EXTRA], ["][OCAML__VERSION_EXTRA]["])])
AC_DEFINE([OCAML_VERSION], [OCAML__VERSION_NUMBER])
AC_DEFINE([OCAML_VERSION_STRING], ["][OCAML__VERSION]["])
AC_DEFINE([OCAML_RELEASE_NUMBER], [OCAML__RELEASE_NUMBER])
# Works out how many "o"s are needed in quoted strings
AC_CONFIG_COMMANDS_PRE(OCAML_QUOTED_STRING_ID)
# Checks for system types
AC_CANONICAL_BUILD
AC_CANONICAL_HOST
# Allow "ocaml" to be used as the last component of the target triplet in case
# we are using a custom toolchain for a freestanding target. To do so, the
# target triplet is temporarily rewritten to "<arch>-none" to compute the
# canonical target
save_target_alias="$target_alias"
AS_CASE([$target_alias],
[*-*-ocaml],
[ac_save_IFS=$IFS
IFS='-'
set x $target_alias
target_alias="$2-none"
IFS=$ac_save_IFS])
AC_CANONICAL_TARGET
target_alias="$save_target_alias"
# Override cross_compiling and ac_tool_prefix variables since the C toolchain is
# used to generate target code when building a cross compiler
cross_compiling=no
AS_IF([test x"$target_alias" != x],
[AS_IF([test x"$build_alias" = x],
[cross_compiling=maybe],
[AS_IF([test x"$build_alias" != x"$target_alias"],
[cross_compiling=yes])])])
AS_IF([test -n "$target_alias"],
[ac_tool_prefix=$target_alias-])
# $cygwin_build_env=true if the build is taking place in any kind of Cygwin-like
# environment (which may include cross-compiling _from_ Cygwin)
# All patterns end with * (cf. build-aux/config.sub)
#
# In Cygwin itself, the mingw-w64 compilers are cross-compilers
# (host=x86_64-pc-cygwin; target=*-w64-mingw32) and $build when running from
# within Cygwin is always *-pc-cygwin.
#
# In MSYS2, the mingw-w64 compilers are normal host compilers, which MSYS2 makes
# available through different Environments (similar to the Microsoft Visual
# Studio Tools Command Prompts; see https://www.msys2.org/docs/environments/).
# It is possible to use MSYS2's "Cygwin" gcc (the equivalent of compiling native
# Cygwin), in which case $build is *-*-cygwin (some older MSYS2 installations
# may report the legacy *-*-msys*)
# The mingw-w64 Environments manually set $build to *-w64-mingw32, but the
# _native_ value inferred by config.guess (which uses uname -s) will be
# *-pc-mingw32 (for the 32-bit _target_ environments, even though MSYS2 is a
# 64-bit build environment) and *-pc-mingw64 (for the 64-bit _target_
# environments).
#
# This leads to the four patterns below, all of which imply that the build is
# taking place on a system where Cygwin's utilities (cygpath, etc.) can be
# expected to be found and its semantics (CYGWIN=winsymlinks:native, etc.) be
# expected to apply.
#
# Note that although build=x86_64-pc-mingw64 will be accepted here, it is highly
# likely that that's a misconfigured environment, and the script will
# subsequently fail if host has not been altered to x86_64-w64-mingw32.
AS_CASE([$build],
[*-*-cygwin*|*-*-msys*|*-*-mingw32*|*-*-mingw64*],
[cygwin_build_env=true],
[cygwin_build_env=false])
# Ensure that AC_CONFIG_LINKS will either create symlinks which are compatible
# with native Windows (i.e. NTFS symlinks, not WSL or Cygwin-emulated ones) or
# use its fallback mechanisms. Native Windows versions of ocamlc/ocamlopt cannot
# interpret either WSL or Cygwin-emulated symlinks.
AS_CASE([$cygwin_build_env,$host],
[true,*-pc-windows|true,*-w64-mingw32*],
[AC_CONFIG_COMMANDS([native-symlinks], [],
[export CYGWIN="\$CYGWIN\${CYGWIN:+ }winsymlinks:nativestrict"
export MSYS="\$MSYS\${MSYS:+ }winsymlinks:nativestrict"])])
# Sanitize the Windows target triplets. After this block, the patterns are:
# *-*-cygwin - Cygwin (the vendor part is always ignored, though it should
# always be 'pc')
# *-w64-mingw32* - mingw-w64. The vendor part is always matched because
# *-pc-mingw* is a likely misconfiguration and the triplet
# matters both for flexlink and for prefixed compilers/tools.
# mingw32* is matched (rather than just mingw32) because some
# cross-compilation environments from Linux may add additional
# information after the mingw32
# *-pc-windows - MSVC. The full -pc-windows is matched because that's a suffix
# which is specifically recognised by our build system (since
# autotools still doesn't have full support for recognising MSVC)
OCAML_CHECK_WINDOWS_TRIPLET([$target])
OCAML_CHECK_WINDOWS_TRIPLET([$host])
# Systems that are known not to work, even in bytecode only.
AS_CASE([$target],
[i386-*-solaris*],
[AC_MSG_ERROR([Building for 32 bits target is not supported. \
If your host is 64 bits, you can try with './configure CC="gcc -m64"' \
(or "cc -m64" if you don't have GCC).])])
# MSVC special case
AS_CASE([$target],
[*-pc-windows],
[AS_IF([test -z "$CC"], [CC=cl])
ccomp_type=msvc
S=asm
SO=dll
outputexe=-Fe
outputobj=-Fo
syslib='$(1).lib'],
[ccomp_type=cc
S=s
SO=so
outputexe='-o '
outputobj='-o '
syslib='-l$(1)'])
AC_CHECK_PROG([csc],[csc],[csc])
AS_IF([test -n "$csc"],
[AS_CASE([$host],
[*-w64-mingw32*|*-pc-windows],
[CSC=csc
CSCFLAGS="/nologo /nowarn:1668"
AS_CASE([$host_cpu], [i*86], [CSCFLAGS="$CSCFLAGS /platform:x86"])],
[AC_MSG_WARN([Mono is not yet supported - C sharp tests disabled])])])
# Environment-specific set-up
dnl The separator should be being treated differently for host/target for
dnl cross-compilers, but the installation layout for cross-compilers is already
dnl incorrect (for example, ld.conf is processed by _both_ the host and target
dnl runtimes), so this is left as target-specific for now.
AS_CASE([$target],
[*-w64-mingw32*|*-pc-windows],
[default_separator='\'],
[default_separator='/'])
# Environment variables that are taken into account
AC_ARG_VAR([AS], [which assembler to use])
AC_ARG_VAR([ASPP], [which assembler (with preprocessor) to use])
AC_ARG_VAR([PARTIALLD], [how to build partial (relocatable) object files])
AC_ARG_VAR([RC], [which resource compiler to use])
AC_ARG_VAR([MANIFEST_TOOL], [which manifest generator to use])
AC_ARG_VAR([FLEXLINKFLAGS],
[Supplementary flags passed to flexlink (Windows targets)])
AC_ARG_VAR([COMPILER_BYTECODE_CFLAGS],
[CFLAGS for compiling C files to be linked with bytecode])
AC_ARG_VAR([COMPILER_BYTECODE_CPPFLAGS],
[CPPFLAGS for compiling C files to be linked with bytecode])
AC_ARG_VAR([COMPILER_NATIVE_CFLAGS],
[CFLAGS for compiling C files to be linked with native code])
AC_ARG_VAR([COMPILER_NATIVE_CPPFLAGS],
[CPPFLAGS for compiling C files to be linked with native code])
# Command-line arguments to configure
AC_ARG_ENABLE([debug-runtime],
[AS_HELP_STRING([--disable-debug-runtime],
[do not build runtime with debugging support])])
AC_ARG_ENABLE([codegen-invariants],
[AS_HELP_STRING([--enable-codegen-invariants],
[enable invariants checks in native codegen])])
AC_ARG_ENABLE([ocamldebug],
[AS_HELP_STRING([--enable-ocamldebug],
[build ocamldebug @<:@default=auto@:>@])],
[],
[enable_ocamldebug=auto])
AC_ARG_ENABLE([debugger],
[AS_HELP_STRING([--enable-debugger],
[alias for --enable-ocamldebug])],
[enable_ocamldebug=$enableval],
[])
AC_ARG_ENABLE([dependency-generation],
[AS_HELP_STRING([--disable-dependency-generation],
[do not compute dependency information for C sources])],
[],
[enable_dependency_generation=auto])
AC_ARG_VAR([DLLIBS],
[which libraries to use (in addition to -ldl) to load dynamic libs])
AC_ARG_ENABLE([instrumented-runtime],
[AS_HELP_STRING([--enable-instrumented-runtime],
[build the instrumented runtime @<:@default=auto@:>@])],
[],
[enable_instrumented_runtime=auto])
AC_ARG_ENABLE([vmthreads], [],
[AS_IF([test "x$enableval" != 'xno'],
[AC_MSG_ERROR(m4_normalize([The vmthreads library is no longer available.
It was deleted in OCaml 4.09.]))])],
[])
AC_ARG_ENABLE([systhreads],
[AS_HELP_STRING([--disable-systhreads],
[disable the Win32/POSIX threads library])])
AC_ARG_ENABLE([tsan],
[AS_HELP_STRING([--enable-tsan],
[enable ThreadSanitizer support @<:@default=no@:>@])],
[],
[enable_tsan=no])
# Preprocessor and linker flags for libunwind (currently only used when TSan is
# enabled)
AC_ARG_VAR([LIBUNWIND_CPPFLAGS],
[C preprocessor flags for libunwind (e.g. -I<location of libunwind headers>)])
AC_ARG_VAR([LIBUNWIND_LDFLAGS],
[linker flags for libunwind (e.g. -L<location of libunwind>])
AC_ARG_ENABLE([graph-lib], [],
[AS_IF([test "x$enableval" != 'xno'],
[AC_MSG_ERROR(m4_normalize([The graphics library is no longer distributed
with OCaml since version 4.09. It is now distributed as a separate
"graphics" package: https://github.com/ocaml/graphics]))])],
[])
AC_ARG_ENABLE([str-lib],
[AS_HELP_STRING([--disable-str-lib],
[do not build the str library])])
AC_ARG_ENABLE([unix-lib],
[AS_HELP_STRING([--disable-unix-lib],
[do not build the unix library])])
AC_ARG_ENABLE([bigarray-lib], [],
[AS_IF([test "x$enableval" != 'xno'],
[AC_MSG_ERROR(m4_normalize([The bigarray-lib option was deleted in OCaml
5.0, as the Bigarray module is now part of the standard library.]))])],
[])
AC_ARG_ENABLE([ocamldoc],
[AS_HELP_STRING([--disable-ocamldoc],
[do not build the ocamldoc documentation system])],
[],
[enable_ocamldoc='auto'])
AC_ARG_WITH([odoc],
[AS_HELP_STRING([--with-odoc],
[build documentation with odoc])])
AC_ARG_ENABLE([ocamlobjinfo],
[AS_HELP_STRING([--disable-ocamlobjinfo],
[do not build ocamlobjinfo])])
AC_ARG_ENABLE([ocamltest],
[AS_HELP_STRING([--disable-ocamltest],
[do not build ocamltest])])
AC_ARG_ENABLE([native-toplevel],
[AS_HELP_STRING([--enable-native-toplevel],
[build the native toplevel])])
AC_ARG_ENABLE([frame-pointers],
[AS_HELP_STRING([--enable-frame-pointers],
[use frame pointers in runtime and generated code])])
AC_ARG_ENABLE([naked-pointers], [],
[AS_IF([test "x$enableval" != 'xno'],
[AC_MSG_ERROR([Naked pointers were prohibited in OCaml 5.0.])])],
[])
AC_ARG_ENABLE([naked-pointers-checker], [],
[AS_IF([test "x$enableval" != 'xno'],
[AC_MSG_ERROR([The naked pointers checker was removed in OCaml 5.0.])])],
[])
AC_ARG_ENABLE([spacetime], [],
[AS_IF([test "x$enableval" != 'xno'],
[AC_MSG_ERROR([spacetime profiling was deleted in OCaml 4.12.])])],
[])
AC_ARG_ENABLE([cfi],
[AS_HELP_STRING([--disable-cfi],
[disable the CFI directives in assembly files])])
AC_ARG_ENABLE([imprecise-c99-float-ops],
[AS_HELP_STRING([--enable-imprecise-c99-float-ops],
[enables potentially imprecise replacement implementations
of C99 float ops if unavailable on this platform])])
AC_ARG_ENABLE([installing-source-artifacts],
[AS_HELP_STRING([--enable-installing-source-artifacts],
[install *.cmt* and *.mli files])])
AC_ARG_ENABLE([installing-bytecode-programs],
[AS_HELP_STRING([--enable-installing-bytecode-programs],
[also install the bytecode versions of programs])])
AC_ARG_ENABLE([native-compiler],
[AS_HELP_STRING([--disable-native-compiler],
[do not build the native compiler])])
AC_ARG_ENABLE([flambda],
[AS_HELP_STRING([--enable-flambda],
[enable flambda optimizations])])
AC_ARG_ENABLE([flambda-invariants],
[AS_HELP_STRING([--enable-flambda-invariants],
[enable invariants checks in flambda])])
AC_ARG_ENABLE([cmm-invariants],
[AS_HELP_STRING([--enable-cmm-invariants],
[enable invariants checks in Cmm])])
AC_ARG_VAR([TARGET_BINDIR],
[location of the runtime binaries on the target system])
AC_ARG_VAR([TARGET_LIBDIR],
[location of the libraries on the target system, to be used for dynlink;
defaults to the value of libdir])
AC_ARG_WITH([target-sh],
[AS_HELP_STRING([--with-target-sh],
[location of Posix sh on the target system])],
[AS_IF([test x"$withval" = 'xno'],
[launch_method_target='exe'],
[launch_method_target="$withval"])],
[launch_method_target=''])
AC_ARG_WITH([additional-stublibsdir],
[AS_HELP_STRING([--with-additional-stublibsdir],
[additional directory for searching for bytecode stub libraries])],
[AS_CASE([$withval],
[no],
[ocaml_additional_stublibs_dir=''],
[yes],
[ocaml_additional_stublibs_dir="..${default_separator}stublibs"],
[ocaml_additional_stublibs_dir="$withval"])],
[ocaml_additional_stublibs_dir=''])
AC_ARG_ENABLE([reserved-header-bits],
[AS_HELP_STRING([--enable-reserved-header-bits=BITS],
[reserve BITS (between 0 and 31) bits in block headers])],
[AS_CASE([$enable_reserved_header_bits],
[[[0-9]]|[[1-2]][[0-9]]|3[[0-1]]],
[reserved_header_bits=$enable_reserved_header_bits],
[AC_MSG_ERROR([invalid argument to --enable-reserved-header-bits])])])
AC_ARG_ENABLE([stdlib-manpages],
[AS_HELP_STRING([--disable-stdlib-manpages],
[do not build or install the library man pages])],
[],
[enable_stdlib_manpages='auto'])
AC_ARG_ENABLE([warn-error],
[AS_HELP_STRING([--enable-warn-error],
[treat C compiler warnings as errors])])
AC_ARG_VAR([WINDOWS_UNICODE_MODE],
[how to handle Unicode under Windows: ansi, compatible])
AC_ARG_ENABLE([force-safe-string], [],
[AS_IF([test "x$enableval" = 'xno'],
[AC_MSG_ERROR([Support for mutable strings was removed in OCaml 5.0.])])],
[])
AC_ARG_VAR([DEFAULT_STRING], [])
AS_IF([test x"$DEFAULT_STRING" = "xunsafe"],
[AC_MSG_ERROR([Support for mutable strings was removed in OCaml 5.0.])])
AC_ARG_ENABLE([flat-float-array],
[AS_HELP_STRING([--disable-flat-float-array],
[do not use flat float arrays])])
AC_ARG_ENABLE([function-sections],
[AS_HELP_STRING([--disable-function-sections],
[do not emit each function in a separate section])],
[],
[enable_function_sections=auto])
AC_ARG_ENABLE([mmap-map-stack],
[AS_HELP_STRING([--enable-mmap-map-stack],
[use mmap to allocate stacks instead of malloc])])
AC_ARG_WITH([relative-libdir],
[AS_HELP_STRING([--with-relative-libdir],
m4_normalize([location of the Standard Library, specified relative to
--bindir (if no argument is given to --with-relative-libdir, defaults to
../lib/ocaml)]))],
[AS_CASE([$withval],
[no],
[bindir_to_libdir=''],
[yes],
[bindir_to_libdir="..${default_separator}lib${default_separator}ocaml"],
[bindir_to_libdir="$withval"])],
[bindir_to_libdir=''])
AC_ARG_ENABLE([suffixing],
[AS_HELP_STRING([--disable-suffixing],
[disable suffixing of runtime executables and shared libraries])],
[AS_IF([test "x$enableval" = 'xno'], [suffixing=false], [suffixing=true])],
[suffixing=true])
AC_ARG_ENABLE([runtime-search],
[AS_HELP_STRING([--enable-runtime-search],
[allow the distribution's bytecode executables to search for ocamlrun])],
[AS_CASE([$enableval],
[no],[],
[yes],[runtime_search='enable'],
[fallback],[runtime_search='fallback'],
[AC_MSG_ERROR(m4_normalize([valid values are yes, no or fallback for
--enable-runtime-search]))])])
AC_ARG_ENABLE([runtime-search-target],
[AS_HELP_STRING([--enable-runtime-search-target],
[allow bytecode executables produced by ocamlc to search for ocamlrun])],
[AS_CASE([$enableval],
[no],[],
[yes],[runtime_search_target='enable'],
[fallback],[runtime_search_target='fallback'],
[AC_MSG_ERROR(m4_normalize([valid values are yes, no or fallback for
--enable-runtime-search-target]))])])
AS_CASE([$suffixing,$runtime_search,$runtime_search_target],
[true,*,*|false,,],[],
[false,*,*],[AC_MSG_ERROR(m4_normalize([--disable-suffixed cannot be used with
--enable-runtime-search or --enable-runtime-search-target]))])
AC_ARG_WITH([afl],
[AS_HELP_STRING([--with-afl],
[use the AFL fuzzer])])
AC_ARG_WITH([flexdll],
[AS_HELP_STRING([--with-flexdll],
[bootstrap FlexDLL from the given sources])],
[AS_IF([test x"$withval" = 'xyes'],[with_flexdll=flexdll])])
AC_ARG_WITH([zstd],
[AS_HELP_STRING([--without-zstd],
[disable compression of compilation artefacts])])
AS_IF([test x"$enable_unix_lib" = "xno"],
[AS_IF([test x"$enable_ocamldebug" = "xyes"],
[AC_MSG_ERROR([ocamldebug requires the unix library])],
[enable_ocamldebug="no"])])
AS_IF([test x"$enable_unix_lib" = "xno" || test x"$enable_str_lib" = "xno"],
[AS_IF([test x"$enable_ocamldoc" = "xyes"],
[AC_MSG_ERROR([ocamldoc requires the unix and str libraries])],
[enable_ocamldoc="no"
build_ocamltex=false])],
[build_ocamltex=true])
AS_IF([test x"$enable_ocamldoc" = "xno"],
[AS_IF([test x"$enable_stdlib_manpages" = "xyes"],
[AC_MSG_ERROR([--enable-stdlib-manpages requires ocamldoc])])
ocamldoc_target=""
ocamldoc_opt_target=""
with_ocamldoc=""
enable_stdlib_manpages=no
build_ocamldoc=false],
[ocamldoc_target=ocamldoc
ocamldoc_opt_target=ocamldoc.opt
with_ocamldoc=ocamldoc
build_ocamldoc=true
optional_libraries="$optional_libraries ocamldoc/odoc_info"
AC_CONFIG_FILES([ocamldoc/META])])
# Are we building a cross-compiler
AS_IF(
[test x"$host" = x"$target"],
[cross_compiler=false],
[# We require a non-cross compiler of the same version
AC_MSG_CHECKING(m4_normalize([if the installed OCaml compiler can build the
cross compiler]))
already_installed_version="$(ocamlc -vnum)"
AS_IF([test x"AC_PACKAGE_VERSION" = x"$already_installed_version"],
[AC_MSG_RESULT([yes (AC_PACKAGE_VERSION)])],
[AC_MSG_RESULT(m4_normalize([no (AC_PACKAGE_VERSION vs
$already_installed_version)]))
AC_MSG_ERROR([exiting])])
cross_compiler=true])
# Bypass libtool check for the manifest tool
AC_CHECK_TOOLS(MANIFEST_TOOL, [mt], :)
# Initialization of libtool
# Allow the MSVC linker to be found even if ld isn't installed.
# User-specified LD still takes precedence.
AS_IF([$cross_compiler],
[AC_CHECK_TARGET_TOOLS([LD],[ld link],[false])],
[AC_CHECK_TOOLS([LD],[ld link])])
# libtool will detect a build-to-host C toolchain but when building an OCaml
# cross compiler we need the C toolchain to build the target runtime so we
# temporarily define host* values as macros for target* values so that the
# proper toolchain is configured. Note that host=target unless we are building a
# cross compiler so this is transparent for the usual use case.
pushdef([host], target)dnl
pushdef([host_alias], target_alias)dnl
pushdef([host_cpu], target_cpu)dnl
pushdef([host_vendor], target_vendor)dnl
pushdef([host_os], target_os)dnl
# libtool expects host_os=mingw for native Windows
# Also, it has been observed that, on some platforms (e.g. msvc) LT_INIT
# alters the CFLAGS variable, so we save its value before calling the macro
# and restore it after the call
old_host_os=$host_os
AS_IF([test x"$host_os" = "xwindows"],[host_os=mingw])
saved_CFLAGS="$CFLAGS"
LT_INIT
CFLAGS="$saved_CFLAGS"
host_os=$old_host_os
popdef([host_os])dnl
popdef([host_vendor])dnl
popdef([host_cpu])dnl
popdef([host_alias])dnl
popdef([host])dnl
OCAML_WITH_NONEXECSTACK_NOTE
OCAML_ASM_SIZE_TYPE_DIRECTIVES
## Find vendor of the C compiler
OCAML_CC_VENDOR
DEP_CC_PREFIX=''
AS_CASE([$host],
[sparc-sun-solaris*],
[DEP_CC="false"],
[*-pc-windows],
[AS_CASE([$ocaml_cc_vendor],
[msvc-*-clang-*],
[DEP_CC="$CC"
DEP_CC_PREFIX='/clang:'],
[AC_CHECK_TOOLS(
[DEP_CC],
[$DEP_CC x86_64-w64-mingw32-gcc i686-w64-mingw32-gcc gcc cc],
[false])
# The C compiler may not be targetting Windows, so explicitly include
# the _WIN32 define
DEP_CPPFLAGS=-D_WIN32])],
[DEP_CC="$CC"])
AS_CASE([$enable_dependency_generation],
[yes],
[AS_IF([test "$DEP_CC" = "false"],
[AC_MSG_ERROR(m4_normalize([The MSVC ports cannot generate dependency
information. Install gcc (or another CC-like compiler)]))],
[compute_deps=true])],
[no], [compute_deps=false],
[AS_IF([test -e .git],
[AS_IF([test "$DEP_CC" = "false"],
[compute_deps=false],
[compute_deps=true])],
[compute_deps=false])])
AS_CASE([$target],
# In config/Makefile.mingw*, we had:
# TARGET=i686-w64-mingw32 and x86_64-w64-mingw32
# TOOLPREF=$(TARGET)-
# ARCMD=$(TOOLPREF)ar
# However autoconf and libtool seem to use ar
# So we let them do, at the moment
[*-pc-windows],
[
mkexe_via_cc_extra_cmd=' && $(call MERGEMANIFESTEXE,$(1))'
libext=lib
AR=""
AS_IF([test "$target_cpu" = "x86_64" ],
[machine="-machine:AMD64 "],
[machine=""])
mklib="link -lib -nologo $machine /out:\$(1) \$(2)"
],
[
mklib="rm -f \$(1) && ${AR} rc \$(1) \$(2)"
])
## In cross-compilation mode, can we run executables produced?
# At the moment, it's required, but the fact is used in C99 function detection
OCAML_TARGET_IS_EXECUTABLE
# Determine how to call the C preprocessor directly.
# Most of the time, calling the C preprocessor through the C compiler is
# desirable and even important.
# In some cases, though, we want to use the C preprocessor only to
# expand macros. In such cases, it is much more convenient to be able
# to invoke it directly rather than through the C compiler, for instance
# because, when invoked directly, the C preprocessor does not require
# to be invoked on a file with a '.c' extension
# We thus figure out how to invoke the C preprocessor directly but
# let the CPP variable untouched, except for the MSVC port where we set it
# manually to make sure the backward compatibility is preserved
AS_CASE([$ocaml_cc_vendor],
[xlc-*],
[CPP="$CC -E -qnoppline" # suppress incompatible XLC line directives
ocamltest_CPP="$CPP"],
[sunc-*],
[CPP="$CC -E -Qn" # suppress generation of Sun PRO ident string
ocamltest_CPP="$CPP"],
[msvc-*],
[CPP="$CC -nologo -EP -TC"
ocamltest_CPP="$CPP 2> nul"],
[CPP="$CC -E -P"
ocamltest_CPP="$CPP"])
# Absolute path to the toplevel source directory
# A sentinel character (X) is added at the end of the directory name
# and then removed, in case the directory name finishes with an odd character.
# (The $(...) construct strips trailing \n characters.)
# Also, it is important to use `printf` rather than `echo` because the
# behaviour of `echo` is indeterminate and uncontrollable if the
# absolute path contains backslashes, which will definitely be the case
# on Windows
# See https://lists.gnu.org/archive/html/autoconf/2019-07/msg00002.html
# for the detailed explanation.
srcdir_abs=$(unset CDPATH; cd -- "$srcdir" && printf %sX "$PWD") || fail
srcdir_abs=${srcdir_abs%X}
AS_CASE([$cygwin_build_env,$host],
[true,*-w64-mingw32*|true,*-pc-windows],
[OCAML_CHECK_LN_ON_WINDOWS
ocamlsrcdir="$(LC_ALL=C.UTF-8 cygpath -w -- "$srcdir_abs")"],
[ln='ln -sf'
ocamlsrcdir="$srcdir_abs"])
# Whether ar supports @FILE arguments
AS_CASE([$lt_cv_ar_at_file],
[no], [ar_supports_response_files=false],
[ar_supports_response_files=true])
# Libraries to build depending on the target
AS_CASE([$target],
[*-w64-mingw32*|*-pc-windows],
[unix_or_win32="win32"
ocamltest_libunix="Some false"
ocamlyacc_wstr_module="yacc/wstr"],
[unix_or_win32="unix"
ocamltest_libunix="Some true"
ocamlyacc_wstr_module=""])
otherlibraries="dynlink runtime_events"
otherlibs="runtime_events"
optional_libraries="$optional_libraries otherlibs/dynlink/dynlink"
lib_dynlink=true
dnl dldir needs to be expanded by autoconf, not by configure, if it were instead
dnl put in $dldir, this would end up in config.status, except that the value
dnl would be missing.
m4_define([dldir], [otherlibs/dynlink])
AC_CONFIG_LINKS(
dldir[/dynlink_cmo_format.mli:file_formats/cmo_format.mli]
dldir[/dynlink_cmxs_format.mli:file_formats/cmxs_format.mli]
dldir[/dynlink_platform_intf.mli:]dldir[/dynlink_platform_intf.ml]
)
m4_undefine([dldir])
lib_runtime_events=true
AS_IF([test x"$enable_unix_lib" != "xno"],
[enable_unix_lib=yes
AC_CONFIG_FILES([otherlibs/unix/META])
otherlibraries="$otherlibraries unix"
otherlibs="$otherlibs unix"
lib_unix=true
AC_CONFIG_LINKS([
otherlibs/unix/unix.ml:otherlibs/unix/unix_${unix_or_win32}.ml
])
ocamltest_unix_impl="real"
unix_directory="otherlibs/unix"
unix_library="${unix_directory}/unix"],
[ocamltest_libunix="None"])
AS_IF([test x"$enable_str_lib" != "xno"],
[otherlibraries="$otherlibraries str"
otherlibs="$otherlibs str"